【GAS入門】QUERYコード一覧！スプレッドシート

グーグルの公式の説明では分かりにくい、QUERYのコード一覧を
説明していきます。

Query Language Reference (Version 0.7)  |  Charts  |  Google for Developers

Learn how to use this language and discover detailed documentation for its classes, functions, and element.

developers.google.com

select

特定の列だけ抽出したい場合に使用します。

=QUERY($C$4:$J$10,"select D,F",-1)
↓D列、F列を抽出

select avg(),count(),max(),min(),sum()

特定の列の集計を行いたい場合に使用します。

=QUERY($C$4:$J$10,"select min(F)",1)
↓F列の最低値を抽出

使える条件は、

where

特定の条件でデータを抽出したい場合に使用します。

=QUERY($C$4:$J$10,"where F>=600",-1)
↓F列(給料)が600以上のデータを抽出します。

使える条件式は、下記の通りとなっています。

また、テキストも検索可能です。
テキストを使う時は、検索したい文字を「'(シングルクオーテーション)」で囲ってください。

and検索も可能

検索はand検索も可能です。

=QUERY($C$3:$J$9,"where D != 'Eng' and date '2005-01-09' > G",-1)
↓D列(職種)がEngでなく、かつ2005年1月9日以降に雇った人を抽出

or検索も可能

or検索も可能です。
下記例は、and検索とor検索を組み合わせています。

=QUERY($C$3:$J$9,"where (D<>'Eng' and I=true) or (D='Sales') or J is null",-1)
↓D列がEngではなく、I列がtrueの場合
　または
　D列がSalesで、かつJ列がnullの場合　を抽出

group by　と　pivot

集計のために使用する関数になります。

そのため、selectの中に、集計文(sum(),avg()などが必要です。)

集計条件は、2パターン設定でき、
・gropu byは集計結果を行方向に出力。
・pivotは集計結果を列方向に出力します。

group by　の例

下記例では、所属ごとに、収入の合計を計算しています。

=QUERY($C$3:$J$9,"select D, sum(F) group by D",-1)
↓
・表題としてD列(所属)を表示
・sum(F)で収入の合計を表示
・集計条件は、gropu by Dで所属ごとで設定。

group byの例2

gropu byの条件を二つ並べると、
・○○かつ△△の人は、何人。
のように検索をかけることができます。

=QUERY($C$4:$J$10,"select I,E, avg(F), count(H) group by I,E",-1)
↓
・表題として、I,E列(シニア判定、ランチタイムの時間)と表示
・収入の平均と、人数を集計。
・集計条件は、シニア判定と、ランチタイムの時間

PIVOTの使い方

PIVOTはgroup byと似ていますが、
列方向に集計結果を展開します。

=QUERY($C$3:$J$9,"select sum(F) pivot D",-1)
↓
・収入の合計を集計
・集計条件は、D列(部署)で列方向に展開

group by と pivot の複合技

group byとpivotを組み合わせると、
2つの条件の集計結果を見栄えよく表示させることができます。

=QUERY($C$3:$J$9,"select E, sum(F) group by E pivot D",1)
↓
・表題として、E列(ランチタイム)を設定。
・収入の合計を集計。
・集計条件は、「E列(ランチタイムの時間ごと)」かつ「D列(所属ごと)」

group byと pivot の注意点

pivot,group byは条件が一致しないと表示されませんので、ご注意ください。

基本的に、

・集計したい条件①＝〇
・集計したい条件②＝◇
・集計対象を設定する。▲

として、

select 〇,sum(▲) group by 〇 pivot ◇

の形で使うとわかりやすいと思います。
sumの部分は、avg,minなどなどを変更してお使いください。

order by (desc) or (asc)

出力を昇順、降順で並び替える場合に使います。

=QUERY($C$4:$J$10,"order by D, F desc",1)
・D列→F列の順番で降順に並び替える。

order by と group by のコラボ　

gropu byなどと組み合わせると集計結果も並び替えることができます。

=QUERY($C$4:$J$10,"select D, max(F) group by D order by max(F)",1)
↓D列を表題にして、
各業種ごとの、F列の最大値を取得、昇順で並べています。

limitで検索結果に表示数に制限をかける

limitを使うと、表示数に制限をかけることができます。

=QUERY($C$4:$J$10,"limit 2",1)
2行まで表示。

offset で行をスキップする。

これはあまり使うタイミングが分からないのですが、
行をスキップすることができます。

limitと組み合わせると間をとることも可能です。

=QUERY($C$4:$J$10,"limit 2 offset 2 ",1)
↓2行目から、2行分表示。

見出しの変更　label

labelを使って見出しの変更ができます。
グラフなどを作るときには便利な機能となっています。

=QUERY($C$4:$J$10,"label D 'Department', C 'Employee Name'",1)
D列のラベルの'Department'、C列のラベルを'Employee Name'に変更

フォーマットを変更

データベースに登録できるフォーマットの形は決まっていますので、
出力結果を変更したい場合は、フォーマット関数を使用する必要があります。

=QUERY($C$4:$J$10,"format F '#,##0.00', G 'dd-MMM-yyyy', I 'Yes!:Not yet'",1)

その他使える関数

その他使る関数を以下に示します。